SendWebSocketString()

Syntax

SendWebSocketString(#WebSocket, String$)

Send a string on the specified WebSocket.

Parameters

#WebSocket	The WebSocket to use. It has to be opened with OpenWebSocket().
String$	The string to send on the WebSocket.

Return value

None.

Example: Simple WebSocket send string

  Procedure Events()
    Select Event()
      Case #PB_Event_Gadget
            
        Select EventGadget()
          Case 0
            ; The server will send back the same string, so we should
            ; get it in the #PB_Event_WebSocket event
            SendWebSocketString(2, "Hello !") 
                      
        EndSelect
    
      Case #PB_Event_WebSocket
        
        Select EventType()
          Case #PB_EventType_Connected
            Debug "WebSocket #" + EventWebSocket() + " connected."
            
          Case #PB_EventType_Closed
            Debug "WebSocket #" + EventWebSocket() + " closed."
            
          Case #PB_EventType_String
            Debug "String recieved on WebSocket #" + EventWebSocket() + "."
            Debug "String content: " + EventString()
            
          Case #PB_EventType_Error
            Debug "Error on WebSocket #" + EventWebSocket() + "."
        EndSelect
    EndSelect
    
  EndProcedure

  BindEvent(#PB_Event_Gadget, @Events())
  BindEvent(#PB_Event_WebSocket, @Events())

  OpenWindow(0, 100, 100, 220, 50, "WebSocket test")
  ButtonGadget(0, 10, 10, 200, 30, "Send string !")

  ; Connect to a free online websocket which send back every command
  If OpenWebSocket(2, "wss://ws.postman-echo.com/raw") 
    Debug "Trying to open the websocket"
  Else
    Debug "Web socket not supported."
  EndIf

See Also

OpenWebSocket(), SendWebSocketData()

Supported OS

All